plugins {
    id 'com.android.application'
}

android {
    namespace 'com.fongmi.android.tv'

    compileSdk 34
    flavorDimensions = ["mode", "api", "abi"]

    defaultConfig {
        applicationId "com.fongmi.android.tv"
        minSdk 21
        //noinspection ExpiredTargetSdkVersion
        targetSdk 28
        versionCode 237
        versionName "0603"
        javaCompileOptions {
            annotationProcessorOptions {
                arguments = ["room.schemaLocation": "$projectDir/schemas".toString()]
            }
        }
    }

    productFlavors {
        leanback {
            dimension "mode"
        }
        mobile {
            dimension "mode"
        }
        java {
            dimension "api"
        }
        python {
            dimension "api"
        }
        x86 {
            dimension "abi"
            ndk { abiFilters "x86" }
        }
        arm64_v8a {
            dimension "abi"
            ndk { abiFilters "arm64-v8a" }
        }
        armeabi_v7a {
            dimension "abi"
            ndk { abiFilters "armeabi-v7a" }
        }
    }

    buildFeatures {
        buildConfig true
        viewBinding true
    }

    buildTypes {
        release {
            minifyEnabled true
            shrinkResources true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    packagingOptions {
        exclude 'META-INF/beans.xml'
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }

    android.applicationVariants.configureEach { variant ->
        variant.outputs.configureEach { output ->
            outputFileName = "${variant.productFlavors[0].name}-${variant.productFlavors[1].name}-${variant.productFlavors[2].name}.apk"
        }
    }

    configurations.configureEach {
        resolutionStrategy {
            force 'com.squareup.okhttp3:okhttp:' + okhttpVersion
        }
    }

    lint {
        disable 'UnsafeOptInUsageError'
    }
}

dependencies {
    implementation project(':hook')
    implementation project(':tvbus')
    implementation project(':catvod')
    implementation project(':quickjs')
    implementation project(':thunder')
    implementation project(':youtube')
    implementation project(':jianpian')
    implementation project(':forcetech')
    implementation project(':ijkplayer')
    pythonImplementation project(':chaquo')
    implementation project(':media-lib-datasource-okhttp')
    implementation project(':media-lib-datasource-rtmp')
    implementation project(':media-lib-decoder-av1')
    implementation project(':media-lib-decoder-ffmpeg')
    implementation project(':media-lib-exoplayer')
    implementation project(':media-lib-exoplayer-dash')
    implementation project(':media-lib-exoplayer-hls')
    implementation project(':media-lib-exoplayer-rtsp')
    implementation project(':media-lib-exoplayer-smoothstreaming')
    implementation project(':media-lib-ui')
    implementation 'androidx.appcompat:appcompat:1.6.1'
    implementation 'androidx.media:media:1.7.0'
    implementation 'androidx.room:room-runtime:2.6.1'
    implementation 'cat.ereza:customactivityoncrash:2.4.0'
    implementation 'com.github.bassaer:materialdesigncolors:1.0.0'
    implementation 'com.github.bumptech.glide:glide:4.16.0'
    implementation 'com.github.bumptech.glide:annotations:4.16.0'
    implementation 'com.github.bumptech.glide:okhttp3-integration:4.16.0'
    implementation 'com.github.bytedance:danmaku-render-engine:0.1.0'
    implementation 'com.github.jahirfiquitiva:TextDrawable:1.0.3'
    implementation 'com.github.thegrizzlylabs:sardine-android:0.9'
    implementation 'com.google.android.material:material:1.12.0'
    implementation 'com.google.net.cronet:cronet-okhttp:0.1.0'
    implementation 'com.google.zxing:core:3.3.0'
    implementation 'com.guolindev.permissionx:permissionx:1.7.1'
    implementation 'com.hierynomus:smbj:0.13.0'
    implementation 'javax.servlet:javax.servlet-api:3.1.0'
    implementation 'org.chromium.net:cronet-embedded:76.3809.111'
    implementation 'org.eclipse.jetty:jetty-client:8.1.21.v20160908'
    implementation 'org.eclipse.jetty:jetty-server:8.1.21.v20160908'
    implementation 'org.eclipse.jetty:jetty-servlet:8.1.21.v20160908'
    implementation 'org.fourthline.cling:cling-core:2.1.1'
    implementation 'org.fourthline.cling:cling-support:2.1.1'
    implementation 'org.greenrobot:eventbus:3.3.1'
    implementation('org.simpleframework:simple-xml:2.7.1') { exclude group: 'stax', module: 'stax-api' exclude group: 'xpp3', module: 'xpp3' }
    implementation(ext: 'aar', name: 'dlna-core', group: 'fongmi', version: 'release')
    leanbackImplementation(ext: 'aar', name: 'dlna-dmr', group: 'fongmi', version: 'release')
    leanbackImplementation 'androidx.leanback:leanback:1.2.0-alpha04'
    leanbackImplementation 'me.jessyan:autosize:1.2.1'
    mobileImplementation(ext: 'aar', name: 'dlna-dmc', group: 'fongmi', version: 'release')
    mobileImplementation 'androidx.biometric:biometric:1.1.0'
    mobileImplementation 'androidx.swiperefreshlayout:swiperefreshlayout:1.1.0'
    mobileImplementation 'com.google.android.flexbox:flexbox:3.0.0'
    mobileImplementation('com.journeyapps:zxing-android-embedded:4.3.0') { transitive = false }
    annotationProcessor 'androidx.room:room-compiler:2.6.1'
    annotationProcessor 'com.github.bumptech.glide:compiler:4.16.0'
}